Функция Pos в Delphi

freestyle

Кто-нибудь знает, какой там используется алгоритм для нахождения подстроки?
Версия Дельфи — 7-ая.

0000

а в исходниках чтоли нет кола?

yolki

нет.
также как нету кода для WriteLn/ReadLn

yolki

а, не.. есть.

procedure       _LStrPos{ const substr : AnsiString; const s : AnsiString ) : Integer};

asm

{     ->EAX     Pointer to substr               }

{       EDX     Pointer to string               }

{     <-EAX     Position of substr in s or 0    }



        TEST    EAX,EAX

        JE      @@noWork



        TEST    EDX,EDX

        JE      @@stringEmpty



        PUSH    EBX

        PUSH    ESI

        PUSH    EDI



        MOV     ESI,EAX                         { Point ESI to substr           }

        MOV     EDI,EDX                         { Point EDI to s                }



        MOV     ECX,[EDI-skew].StrRec.length    { ECX = Length(s)               }



        PUSH    EDI                             { remember s position to calculate index        }



        MOV     EDX,[ESI-skew].StrRec.length    { EDX = Length(substr)          }



        DEC     EDX                             { EDX = Length(substr) - 1              }

        JS      @@fail                          { < 0 ? return 0                        }

        MOV     AL,[ESI]                        { AL = first char of substr             }

        INC     ESI                             { Point ESI to 2'nd char of substr      }



        SUB     ECX,EDX                         { #positions in s to look at    }

                                                { = Length(s) - Length(substr) + 1      }

        JLE     @@fail

@@loop:

        REPNE   SCASB

        JNE     @@fail

        MOV     EBX,ECX                         { save outer loop counter               }

        PUSH    ESI                             { save outer loop substr pointer        }

        PUSH    EDI                             { save outer loop s pointer             }



        MOV     ECX,EDX

        REPE    CMPSB

        POP     EDI                             { restore outer loop s pointer  }

        POP     ESI                             { restore outer loop substr pointer     }

        JE      @@found

        MOV     ECX,EBX                         { restore outer loop counter    }

        JMP     @@loop



@@fail:

        POP     EDX                             { get rid of saved s pointer    }

        XOR     EAX,EAX

        JMP     @@exit



@@stringEmpty:

        XOR     EAX,EAX

        JMP     @@noWork



@@found:

        POP     EDX                             { restore pointer to first char of s    }

        MOV     EAX,EDI                         { EDI points of char after match        }

        SUB     EAX,EDX                         { the difference is the correct index   }

@@exit:

        POP     EDI

        POP     ESI

        POP     EBX

@@noWork:

end;